global input Select V me in
set Select(0) {}
set in(SELECT) 0
# - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - #
# Handle a <SELECT> tag.  We create a framed listbox with a scrollbar, and
# insert it into the text widget w.  We also record in Select() the name of
# the widget.
# 
proc tagSELECT {w t att} {
	global B C V R me form N Input input Select in
	if {$V>2} {puts "$me/tagSELECT: w={$w} t={$t} att={$att}"}
	incr in(SELECT)
	set i [incr input]
	set Input(E$i) {}
	set Input(S$i) 0	;# Size is number of options to show.
	set Input(M$i) 0	;# Maximum size of option string.
	set Input(T$i) {}
	set Input(V$i) {}
	if {$V>2} {puts "$me/tagSELECT: SELECT item $i level $in(SELECT) att=\"$att\" ..."}
	set fr $w.fr$i
	if {$V>2} {puts "$me/tagSELECT: SELECT item $i frame $fr ..."}
	if [winfo exists $w.fr$i] {destroy $w.fr$i}
	set Select($i) $fr
	frame $fr -bd $B -relief $R
	if {$V>2} {puts "$me/tagSELECT: SELECT item $i frame $fr created."}
	$w window create insert -window $fr
	if {$V>2} {puts "$me/tagSELECT: SELECT item $i frame $fr inserted."}
	listbox   $fr.lb -bd 0 -relief $R -height 1 -xscrollcommand "$fr.sx set" -yscrollcommand "$fr.sy set"
	scrollbar $fr.sx -bd 0 -relief $R -width 6 -command "$fr.lb xview" -orient horizontal
	scrollbar $fr.sy -bd 0 -relief $R -width 6 -command "$fr.lb yview" -orient vertical
	button    $fr.xx -bd 0 -relief $R -font -------2 -text {} -command "$fr.lb selection clear 0 end"
	BindHelp $fr.xx {Clear selection}
	grid columnconfigure $fr 1 -weight 0
	grid    rowconfigure $fr 1 -weight 0
	grid $fr.lb -in $fr -row 0 -column 0 -sticky news
	grid $fr.sy -in $fr -row 0 -column 1 -sticky news
	grid $fr.sx -in $fr -row 1 -column 0 -sticky news
	grid $fr.xx -in $fr -row 1 -column 1 -sticky news
	set Input(E$i) "GetSel $fr.lb"
	while {$att != {}} {
		if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE {$att}"}
		if {[regexp {^([A-Za-z]+)="([^"]*)"[ 	]*(.*)$} $att {} a v att]
		||  [regexp {^([A-Za-z]+)=([^ 	]*)[ 	]*(.*)$} $att {} a v att]} {
			if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE a={$a} v={$v}"}
			switch  [string toupper $a] {
			NAME {
				if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE NAME v={$v}"}
				set Input(N$i) $v
				if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE NAME Input(N$i)=\"$Input(N$i)\""}
				lappend Input(I$form) $i
				if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE NAME Input(I$form)={$Input(I$form)}"}
			  }
			SIZE {
				if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE SIZE v={$v}"}
				set Input(S$i) $v
				if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE SIZE Input(S$i)={$Input(S$i)}"}
				$fr.lb config -height $v
			  }
			default {
				if {$V>2} {puts "$me/tagSELECT: ATTRIBUTE a={$a} unknown."}
			  }
			}
		} elseif [regexp -nocase {^(multiple)[ 	]*(.*)} $att {} a att] {
			if {$V>2} {puts "$me/tagINPUT: ATTRIBUTE MULTIPLE."}
			$fr.lb config -selectmode multiple
		} else {
			if {$V>2} {puts "$me/tagINPUT: UNKNOWN {$att}"}
			regsub {^[^ 	]*[ 	]*} $att {} att
			if {$V>2} {puts "$me/tagINPUT: att={$att}"}
		}
	}
}

# - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - #
# Terminate a <SELECT> tag.
#
proc endSELECT w {
	global in LC
	incr in(SELECT) -1
	HSP $w {}
	set LC {}
}

# - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - #
# Return the selected item(s) from a listbox.  It's possible that nothing  is
# selected,  in which case we return a null string.  For multiple selections,
# we return them all with newlines in between.
#
proc GetSel {lb} {
	global V me
	if [catch {$lb curselection} x] {
		if {$V>2} {puts "$me/GetSel: $lb has nothing selected."}
		return {}
	}
	if {$V>2} {puts "$me/GetSel: $lb has {$x} selected."}
	set v {}
	set sep {}
	foreach s $x {
		if {$V>2} {puts "$me/GetSel: Get $s."}
		set v "$v$sep[$lb get $s]"
		if {$V>2} {puts "$me/GetSel: Got v=\"$v\""}
		set sep ,
	}
	if {$V>2} {puts "$me/GetSel: Return \"$v\""}
	return $v
}

# - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - #
# Process an <OPTION> tag. The tricky thing here is that the value may not be
# in the tag's VALUE field, but may be just text that follows the tag.  There
# is no </OPTION> terminator to tell us the end of  the  text.   We  use  the
# kludge  of assuming that the option is on the same line, and using whatever
# text follows, up to a '<' or newline, whichever comes first. This is one of
# the reasons that the current text line is kept in the global Src variable.
#
proc tagOPTION {w t att} {
	global B C V R me Input input Select Src in
	if {$V>2} {puts "$me/tagOPTION: w={$w} t={$t} a={$att}"}
	if {$V>2} {puts "$me/tagOPTION: Src=\"$Src\""}
	set fr $Select([set i $input])
	if [regexp {^(.*)(<.*)} $Src {} opt Src] {
		set v [string trim $opt]
	} else {
		set v [string trim $Src]
		set Src {}
	}
	if {[set w [string length $v]] > $Input(M$i)} {
		$fr.lb config -width [set Input(M$i) $w]
	}
	if {$V>2} {puts "$me/tagOPTION: v={$v} w=$w Input(M$i)=$Input(M$i)"}
	if {$V>4} {puts "$id: $fr.lb insert end \"$v\""}
	$fr.lb insert end $v
}